cmake_minimum_required(VERSION "3.27")

project("kernel"
  DESCRIPTION "An educational OS kernel"
  HOMEPAGE_URL "https://gitlab.ost.ch/teachos/kernel"
  VERSION "0.0.1"
  LANGUAGES ASM C CXX
)

set(CMAKE_MODULE_PATH "${PROJECT_SOURCE_DIR}/cmake/Modules")

include("ElfTransformations")
include("GenerateBootableIso")

#[============================================================================[
# Global Build System Configuration
#]============================================================================]

set(CMAKE_RUNTIME_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin")
set(CMAKE_ARCHIVE_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/lib")
set(CMAKE_INTERPROCEDURAL_OPTIMIZATION YES)

set(CMAKE_CXX_STANDARD "20")
set(CMAKE_CXX_STANDARD_REQUIRED YES)
set(CMAKE_CXX_EXTENSIONS NO)

add_compile_options(
  "$<$<CXX_COMPILER_ID:GNU>:-Wall>"
  "$<$<CXX_COMPILER_ID:GNU>:-Wextra>"
  "$<$<CXX_COMPILER_ID:GNU>:-Werror>"
  "$<$<CXX_COMPILER_ID:GNU>:-pedantic-errors>"
)

#[============================================================================[
# Kernel Executable
#]============================================================================]

add_executable("kernel")

add_subdirectory("libs")
add_subdirectory("kern")
add_subdirectory("arch")

target_link_libraries("kernel" PRIVATE
    "arch::${CMAKE_SYSTEM_PROCESSOR}"
    "os::kern"
)

target_link_options("kernel" PRIVATE
    "-no-pie"
    "-nostdlib"
)

target_disassemble("kernel")
target_extract_debug_symbols("kernel")
target_strip("kernel")

target_generate_bootable_iso("kernel")