add_library("kernel_objs" OBJECT
    # Platform-independent KAPI implementation
    "kapi/acpi.cpp"
    "kapi/boot_modules.cpp"
    "kapi/cio.cpp"
    "kapi/cpu.cpp"
    "kapi/devices.cpp"
    "kapi/devices/bus.cpp"
    "kapi/devices/cpu.cpp"
    "kapi/devices/device.cpp"
    "kapi/interrupts.cpp"
    "kapi/memory.cpp"
    "kapi/system.cpp"

    # KSTD OS Implementation
    "kstd/os.cpp"
    "kstd/print.cpp"

    # Kernel Implementation
    "src/acpi/manager.cpp"
    "src/memory/bitmap_allocator.cpp"
    "src/memory/block_list_allocator.cpp"
    "src/memory/mmio_allocator.cpp"
    "src/memory.cpp"
    "src/devices/block_device.cpp"
    "src/devices/block_device_utils.cpp"
    "src/devices/root_bus.cpp"
    "src/devices/storage/controller.cpp"
    "src/devices/storage/management.cpp"
    "src/devices/storage/ram_disk/controller.cpp"
    "src/devices/storage/ram_disk/device.cpp"
    "src/filesystem/devfs/filesystem.cpp"
    "src/filesystem/devfs/inode.cpp"
    "src/filesystem/ext2/filesystem.cpp"
    "src/filesystem/ext2/inode.cpp"
    "src/filesystem/dentry.cpp"
    "src/filesystem/device_inode.cpp"
    "src/filesystem/file_descriptor_table.cpp"
    "src/filesystem/filesystem.cpp"
    "src/filesystem/inode.cpp"
    "src/filesystem/mount_table.cpp"
    "src/filesystem/mount.cpp"
    "src/filesystem/open_file_description.cpp"
    "src/filesystem/rootfs/filesystem.cpp"
    "src/filesystem/rootfs/inode.cpp"
    "src/filesystem/vfs.cpp"
)

target_include_directories("kernel_objs" PUBLIC
    "include"
)

target_link_libraries("kernel_objs" PUBLIC
    "os::kapi"
)

file(GLOB_RECURSE KERNEL_HEADERS RELATIVE ${CMAKE_CURRENT_SOURCE_DIR} "include/**.hpp")

target_sources("kernel_objs" PUBLIC
    FILE_SET HEADERS
    BASE_DIRS "include"
    FILES
    ${KERNEL_HEADERS}
)

add_library("os::kernel" ALIAS "kernel_objs")

if(CMAKE_CROSSCOMPILING)
  add_executable("kernel"
        "src/main.cpp"
        "src/memory/operators.cpp"
    )

  target_link_libraries("kernel" PRIVATE
        "os::arch"
        "os::kernel"
    )

  target_link_options("kernel" PRIVATE
        "-T${KERNEL_LINKER_SCRIPT}"
        "-no-pie"
        "-nostdlib"
    )

  set_property(TARGET "kernel"
        APPEND
        PROPERTY LINK_DEPENDS
        "${KERNEL_LINKER_SCRIPT}"
    )

  target_disassemble("kernel")
  target_extract_debug_symbols("kernel")
  target_strip("kernel")

  target_generate_bootable_iso("kernel")
else()
  enable_coverage("kernel_objs")

  add_library("kernel_test_support" OBJECT
        "src/test_support/kapi/cpu.cpp"
        "src/test_support/kapi/cio.cpp"
        "src/test_support/kapi/interrupts.cpp"
        "src/test_support/kapi/memory.cpp"
        "src/test_support/log_buffer.cpp"
        "src/test_support/output_device.cpp"
        "src/test_support/page_mapper.cpp"
        "src/test_support/simulated_memory.cpp"
        "src/test_support/state_reset_listener.cpp"
    )
  add_library("os::kernel_test_support" ALIAS "kernel_test_support")

  target_link_libraries("kernel_test_support" PUBLIC
        "os::kernel"
        "Catch2::Catch2WithMain"
    )

  add_executable("kernel_tests"
        # KAPI Shim Tests
        "kapi/cpu.tests.cpp"
        "kapi/system.tests.cpp"

        # KSTD Shim Tests
        "kstd/print.tests.cpp"

        # Memory Subsystem Tests
        "src/memory/bitmap_allocator.tests.cpp"
        "src/memory/block_list_allocator.tests.cpp"

        # Filesystem Subsystem Tests
        "src/filesystem/dentry.tests.cpp"

        # Storage Subsystem Tests
        "src/devices/storage/ram_disk/device.tests.cpp"
    )
  add_executable("os::kernel_tests" ALIAS "kernel_tests")

  target_link_libraries("kernel_tests" PRIVATE
        "os::kernel"
        "os::kernel_test_support"
    )

  set_target_properties("kernel_tests" PROPERTIES
        C_CLANG_TIDY ""
        CXX_CLANG_TIDY ""
    )

  enable_coverage("kernel_tests")
  catch_discover_tests("os::kernel_tests")
endif()