From 5d8f799a1171f92054d4b45ba130cd7fdad0bd01 Mon Sep 17 00:00:00 2001
From: Felix Morgner <felix.morgner@gmail.com>
Date: Fri, 23 May 2025 14:04:27 +0200
Subject: app: prepare restructuring

---
 gui/ui/CMakeLists.txt | 59 +++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 59 insertions(+)
 create mode 100644 gui/ui/CMakeLists.txt

(limited to 'gui/ui/CMakeLists.txt')

diff --git a/gui/ui/CMakeLists.txt b/gui/ui/CMakeLists.txt
new file mode 100644
index 0000000..1584479
--- /dev/null
+++ b/gui/ui/CMakeLists.txt
@@ -0,0 +1,59 @@
+# Library
+
+file(GLOB_RECURSE UI_FILES RELATIVE "${CMAKE_CURRENT_SOURCE_DIR}/src" CONFIGURE_DEPENDS "*.ui")
+file(GLOB_RECURSE UI_SOURCES RELATIVE "${CMAKE_CURRENT_SOURCE_DIR}" CONFIGURE_DEPENDS "src/*.cpp")
+file(GLOB_RECURSE UI_TESTS RELATIVE "${CMAKE_CURRENT_SOURCE_DIR}" CONFIGURE_DEPENDS "tests/*.cpp")
+
+add_library("ui" ${UI_SOURCES})
+add_library("turns::ui" ALIAS "ui")
+
+target_compile_options("ui" PUBLIC
+  "$<$<CXX_COMPILER_ID:GNU,Clang>:-Wall>"
+  "$<$<CXX_COMPILER_ID:GNU,Clang>:-Wextra>"
+  "$<$<CXX_COMPILER_ID:GNU,Clang>:-Werror>"
+  "$<$<CXX_COMPILER_ID:GNU,Clang>:-pedantic-errors>"
+)
+
+target_include_directories("ui" PUBLIC
+  "include"
+)
+
+target_link_libraries("ui" PUBLIC
+  "turns::core"
+  "turns::lang"
+ 
+  "adwaitamm::adwaitamm"
+  "PkgConfig::gtkmm"
+)
+
+target_add_glib_resources("ui"
+  PREFIX "/ch/arknet/Turns/"
+  WORKING_DIRECTORY "${CMAKE_CURRENT_SOURCE_DIR}/src"
+  UI_FILES ${UI_FILES}
+)
+
+enable_coverage("ui")
+
+# Tests
+
+get_target_property(TRANSLATIONS_BINARY_DIR "lang" BINARY_DIR)
+
+add_executable("ui-tests" ${UI_TESTS})
+
+target_compile_definitions("ui-tests" PUBLIC
+  "TESTLOCALEDIR=\"${TRANSLATIONS_BINARY_DIR}\""
+)
+
+target_link_libraries("ui-tests" PRIVATE
+  "Catch2::Catch2WithMain"
+  
+  "$<$<CXX_COMPILER_ID:GNU,Clang>:-Wl,--whole-archive>"
+  "turns::ui"
+  "$<$<CXX_COMPILER_ID:GNU,Clang>:-Wl,--no-whole-archive>"
+)
+
+target_link_options("ui-tests" PRIVATE
+  "$<$<AND:$<CXX_COMPILER_ID:GNU,Clang>,$<CONFIG:Debug>>:--coverage>"
+)
+
+catch_discover_tests("ui-tests")
-- 
cgit v1.2.3