1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
|
# Library
add_library("app"
"src/application.cpp"
"src/widgets/participant_row.cpp"
"src/widgets/turn_order_view.cpp"
"src/windows/participant_editor.cpp"
"src/windows/tracker.cpp"
)
add_library("turns::app" ALIAS "app")
target_compile_options("app" PUBLIC
"$<$<CXX_COMPILER_ID:GNU,Clang>:-Wall>"
"$<$<CXX_COMPILER_ID:GNU,Clang>:-Wextra>"
"$<$<CXX_COMPILER_ID:GNU,Clang>:-Werror>"
"$<$<CXX_COMPILER_ID:GNU,Clang>:-pedantic-errors>"
PRIVATE
"$<$<AND:$<CXX_COMPILER_ID:GNU,Clang>,$<CONFIG:Debug>>:-fprofile-arcs>"
"$<$<AND:$<CXX_COMPILER_ID:GNU,Clang>,$<CONFIG:Debug>>:-ftest-coverage>"
)
target_include_directories("app" PUBLIC
"include"
)
target_link_libraries("app" PUBLIC
"$<$<AND:$<CXX_COMPILER_ID:GNU,Clang>,$<CONFIG:Debug>>:gcov>"
"PkgConfig::adwaita"
"PkgConfig::gtkmm"
"turns::domain"
"turns::lang"
"$<$<CXX_COMPILER_ID:GNU,Clang>:-Wl,--whole-archive>"
"turns::res"
"$<$<CXX_COMPILER_ID:GNU,Clang>:-Wl,--no-whole-archive>"
)
# Application
add_executable("exe"
"src/main.cpp"
)
target_link_libraries("exe" PRIVATE
"turns::app"
)
set_target_properties("exe" PROPERTIES
OUTPUT_NAME "turns"
)
install(TARGETS "exe"
RUNTIME DESTINATION "${CMAKE_INSTALL_BINDIR}"
)
configure_file("desktop.in"
"turns.desktop"
)
install(FILES
"${CMAKE_CURRENT_BINARY_DIR}/turns.desktop"
DESTINATION "${CMAKE_INSTALL_DATAROOTDIR}/applications"
)
# Tests
add_executable("app-tests"
"tests/widgets/participant_row.cpp"
"tests/windows/participant_editor.cpp"
"tests/windows/tracker.cpp"
)
target_link_libraries("app-tests" PRIVATE
"Catch2::Catch2"
"turns::app"
"turns::gtk-test-main"
)
catch_discover_tests("app-tests")
|
