blob: 3922b92ffb6678dc2a60e457e7532bbfcbade009 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
|
# SPDX-FileCopyrightText: 2025 Felix Morgner <felix.morgner@gmail.com>
# SPDX-License-Identifier: LGPL-2.1-only
find_program(GLIB_COMPILE_RESOURCES
NAMES "glib-compile-resources"
REQUIRED
)
function(target_add_glib_resources TARGET)
set(SINGLE_VALUE_ARGS "PREFIX" "WORKING_DIRECTORY")
set(MULTI_VALUE_ARGS "CSS_FILES" "UI_FILES")
cmake_parse_arguments(
PARSE_ARGV 1
""
"${OPTIONS}"
"${SINGLE_VALUE_ARGS}"
"${MULTI_VALUE_ARGS}"
)
# Sanity Checks
if(NOT TARGET "${TARGET}")
message(FATAL_ERROR "Target '${TARGET}' does not exist")
endif()
if(NOT _PREFIX)
message(FATAL_ERROR "Glib resource prefix not defined")
endif()
if(NOT _WORKING_DIRECTORY)
set(_WORKING_DIRECTORY "${CMAKE_CURRENT_SOURCE_DIR}")
endif()
# File Names
set(GLIB_RESOURCE_C_FILE "${CMAKE_CURRENT_BINARY_DIR}/${TARGET}.gresource.c")
set(GLIB_RESOURCE_MANIFEST "${CMAKE_CURRENT_BINARY_DIR}/${TARGET}.gresource.xml")
# Manifest File
foreach(UI_FILE IN LISTS _UI_FILES)
string(APPEND GLIB_RESOURCE_FILES " <file compressed=\"true\" preprocess=\"xml-stripblanks\">${UI_FILE}</file>\n")
endforeach()
foreach(CSS_FILE IN LISTS _CSS_FILES)
string(APPEND GLIB_RESOURCE_FILES " <file compressed=\"true\">${CSS_FILE}</file>\n")
endforeach()
string(STRIP "${GLIB_RESOURCE_FILES}" GLIB_RESOURCE_FILES)
set(GLIB_RESOURCE_PREFIX "${_PREFIX}")
configure_file("${PROJECT_SOURCE_DIR}/cmake/Modules/GlibCompileResources.in"
"${GLIB_RESOURCE_MANIFEST}"
)
# Source Generation
foreach(FILE IN LISTS _CSS_FILES _UI_FILES)
list(APPEND _DEPS "${_WORKING_DIRECTORY}/${FILE}")
endforeach()
add_custom_command(OUTPUT "${GLIB_RESOURCE_C_FILE}"
WORKING_DIRECTORY "${_WORKING_DIRECTORY}"
COMMAND "${GLIB_COMPILE_RESOURCES}"
ARGS
"--target=${GLIB_RESOURCE_C_FILE}"
"--generate-source"
"--internal"
"${GLIB_RESOURCE_MANIFEST}"
VERBATIM
MAIN_DEPENDENCY "${GLIB_RESOURCE_MANIFEST}"
DEPENDS
${_DEPS}
)
# Target Inclusion
target_sources("${TARGET}" PRIVATE
"${GLIB_RESOURCE_C_FILE}"
)
endfunction()
# <file preprocess="xml-stripblanks">bookie.ui</file>
|
