blob: c9b4e353dce40905e151f9a852de1048d3712032 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
|
cmake_minimum_required(VERSION "3.27")
project("kernel"
DESCRIPTION "An educational OS kernel"
HOMEPAGE_URL "https://gitlab.ost.ch/teachos/kernel"
VERSION "0.0.1"
LANGUAGES ASM C CXX
)
set(CMAKE_MODULE_PATH "${PROJECT_SOURCE_DIR}/cmake/Modules")
include("ElfTransformations")
include("GenerateBootableIso")
#[============================================================================[
# Global Build System Options
#]============================================================================]
option(TEACHOS_ENABLE_LINTING "Enable linting during build" ON)
#[============================================================================[
# Global Build System Configuration
#]============================================================================]
set(CMAKE_RUNTIME_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin")
set(CMAKE_ARCHIVE_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/lib")
set(CMAKE_INTERPROCEDURAL_OPTIMIZATION YES)
set(CMAKE_CXX_STANDARD "23")
set(CMAKE_CXX_STANDARD_REQUIRED YES)
set(CMAKE_CXX_EXTENSIONS NO)
add_compile_options(
"$<$<CXX_COMPILER_ID:GNU>:-Wall>"
"$<$<CXX_COMPILER_ID:GNU>:-Wextra>"
"$<$<CXX_COMPILER_ID:GNU>:-Werror>"
"$<$<CXX_COMPILER_ID:GNU>:-pedantic-errors>"
)
#[============================================================================[
# Global Linting Configuration
#]============================================================================]
find_program(CLANG_TIDY_EXE "clang-tidy")
if(CLANG_TIDY_EXE AND TEACHOS_ENABLE_LINTING)
set(CMAKE_C_CLANG_TIDY "${CLANG_TIDY_EXE}")
set(CMAKE_CXX_CLANG_TIDY "${CLANG_TIDY_EXE}")
endif()
#[============================================================================[
# Global Documentation Configuration
#]============================================================================]
find_package(Doxygen "1.10")
if(Doxygen_FOUND)
doxygen_add_docs("docs"
ALL
COMMENT "Generating documentation"
CONFIG_FILE "${CMAKE_CURRENT_SOURCE_DIR}/Doxyfile"
)
endif()
#[============================================================================[
# Kernel Executable
#]============================================================================]
add_subdirectory("arch/${CMAKE_SYSTEM_PROCESSOR}")
add_subdirectory("kapi")
add_subdirectory("libs")
add_executable("kernel"
"kernel/src/kstd.cpp"
"kernel/src/main.cpp"
# Platform Independent KAPI implementation
"kernel/src/kapi/cio.cpp"
"kernel/src/kapi/memory.cpp"
"kernel/src/kapi/system.cpp"
)
target_include_directories("kernel" PRIVATE
"kernel/include"
)
target_link_libraries("kernel" PRIVATE
"os::arch"
"os::kapi"
)
target_link_options("kernel" PRIVATE
"-T${KERNEL_LINKER_SCRIPT}"
"-no-pie"
"-nostdlib"
)
set_property(TARGET "kernel"
APPEND
PROPERTY LINK_DEPENDS
"${KERNEL_LINKER_SCRIPT}"
)
target_disassemble("kernel")
target_extract_debug_symbols("kernel")
target_strip("kernel")
target_generate_bootable_iso("kernel")
|
