1 files changed, 38 insertions, 0 deletions
diff --git a/source/lib/proto/CMakeLists.txt b/source/lib/proto/CMakeLists.txt
new file mode 100644
index 0000000..9967a95
--- /dev/null
+++ b/source/lib/proto/CMakeLists.txt
@@ -0,0 +1,38 @@
+cmake_path(GET CMAKE_CURRENT_SOURCE_DIR STEM LIB_NAME)
+
+file(GLOB_RECURSE LIB_HEADERS RELATIVE "${CMAKE_CURRENT_SOURCE_DIR}" CONFIGURE_DEPENDS "**/*.hpp")
+file(GLOB_RECURSE LIB_SOURCES RELATIVE "${CMAKE_CURRENT_SOURCE_DIR}" CONFIGURE_DEPENDS "**/*.cpp")
+
+find_package("fmt" REQUIRED)
+
+add_library("wanda-${LIB_NAME}"
+    ${LIB_SOURCES}
+)
+
+target_sources("wanda-${LIB_NAME}" INTERFACE
+    FILE_SET HEADERS
+    FILES ${LIB_HEADERS}
+    BASE_DIRS "include"
+)
+
+target_include_directories("wanda-${LIB_NAME}" PUBLIC
+    "$<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}/include>"
+)
+
+target_include_directories("wanda-${LIB_NAME}" SYSTEM PUBLIC
+    "$<INSTALL_INTERFACE:include>"
+)
+
+target_compile_features("wanda-${LIB_NAME}" PUBLIC
+    "cxx_std_20"
+)
+
+target_link_libraries("wanda-${LIB_NAME}" PUBLIC
+    "fmt::fmt"
+)
+
+install(TARGETS "wanda-${LIB_NAME}"
+    FILE_SET HEADERS
+)
+
+add_library("wanda::${LIB_NAME}" ALIAS "wanda-${LIB_NAME}")